AbstractTween.as

Go to the documentation of this file.

import com.mosesSupposes.fuse.PennerEasing;

import gugga.collections.HashTable;
import gugga.utils.DebugUtils;

class gugga.tween.AbstractTween 
{
        private var mInitialValues : HashTable;
        
        private var mSubject : Object;
        public function get Subject() : Object
        {
                return mSubject;
        }
        
        public var mTweeningProperties : HashTable;
        public function get TweeningProperties() : HashTable
        {
                return mTweeningProperties;
        }
        
        public var Duration : Number = 10;
        
        public var EasingEquation : Function = PennerEasing.linear;
        
        public var TweenFinishedDelegate : Function;
        public var TweenUpdateDelegate : Function;
        
        public var Option1 : Number;
        public var Option2 : Number;
        
        private var mDurationElapsed : Number = 0;
        public function get DurationElapsed() : Number
        {
                return mDurationElapsed;
        }
        
        public function get Finished() : Boolean
        {
                return (mDurationElapsed >= Duration);
        }
        
        public function AbstractTween(aSubject:Object, aTweeningProperties:HashTable) 
        {
                super();
                
                mSubject = aSubject;
                
                mTweeningProperties = new HashTable();
                mInitialValues = new HashTable();
                
                for (var key:String in aTweeningProperties)
                {
                        mInitialValues[key] = aSubject[key];
                        mTweeningProperties[key] = aTweeningProperties[key];
                }
        }
        
        public function update() : Void
        {
                increaseDurationElapsed();
                
                for (var key:String in mTweeningProperties)
                {
                        mSubject[key] = EasingEquation(
                                mDurationElapsed,
                                mInitialValues[key],
                                mTweeningProperties[key] - mInitialValues[key],
                                Duration,
                                Option1,
                                Option2
                        );
                }
                
                TweenUpdateDelegate();
                
                if(Finished)
                {
                        TweenFinishedDelegate();
                }
        }       
        
        private function increaseDurationElapsed() : Void 
        {
                throw new Error("Not implemented");
        }
}

---