BrowserHistoryManager.as

Go to the documentation of this file.

import mx.utils.Delegate;

import gugga.browser.BrowserHistory;
import gugga.commands.CommandManager;
import gugga.common.DeepLinksSerializer;
class gugga.browser.BrowserHistoryManager 
{
        private static var COMMAND_INDEX_KEY : String = "commandIndex";
        
        private static var mInstance : BrowserHistoryManager = null;
        
        private function BrowserHistoryManager()
        {
                super();
                
                BrowserHistory.Instance.addEventListener("changed", 
                        Delegate.create(this, onBrowserHistoryChanged));
                CommandManager.Instance.addEventListener("commandBufferContentChanged", 
                        Delegate.create(this, onCommandBufferContentChanged));  
        }
        
        public static function initialize() : Void
        {
                if(available)
                {
                        if(mInstance == null)
                        {
                                mInstance = new BrowserHistoryManager();
                        }
                }
        }
        
        public static function get available() : Boolean
        {
                return BrowserHistory.available;
        }
        
        private function onBrowserHistoryChanged(ev) : Void 
        {
                var commandIndex : Number = parseInt(String(ev.record[COMMAND_INDEX_KEY]), 10);
                if(isNaN(commandIndex))
                {
                        commandIndex = -1;
                }
                CommandManager.Instance.navigate(commandIndex);
        }
        
        private function onCommandBufferContentChanged(ev) : Void 
        {
                var recordObject : Object = new Object();
                
                recordObject[COMMAND_INDEX_KEY] = ev.currentCommandIndex;
                DeepLinksSerializer.serializeCurrentNavigationPath(recordObject);
                
                BrowserHistory.Instance.addHistory(recordObject);       
        }
}

---