ObjectHashTable.as

Go to the documentation of this file.

import gugga.utils.HashUtil;
import gugga.collections.IHashTable;
import gugga.collections.IIterator;
import gugga.collections.ArrayListIterator;
import gugga.collections.ArrayList;

class gugga.collections.ObjectHashTable extends Object implements IHashTable
{
        public function add(aKey, aObject : Object) : Void
        {
                var hash : String = HashUtil.hash(aKey);
                this[hash] = aObject;
        }
        
        public function remove(aKey) : Object
        {
                var hash : String = HashUtil.hash(aKey);
                var result : Object = this[hash]; 
                delete this[hash];
                return result;
        }
        
        public function containsValue(aObject:Object) : Boolean
        {               
                var result : Boolean = false;
                
                for(var hash : String in this)
                {
                        if(this[hash] == aObject)
                        {
                                result = true;
                        }
                }

                return result;
        }
        
        public function containsKey(aKey):Boolean
        {
                var hash : String = HashUtil.hash(aKey);
                
                var result:Boolean = false;
                if(this[hash] != undefined && this[hash] != null)
                {
                        result = true;
                }
                
                return result;
        }
        
        public function getKeyByValue(aValue:Object):String
        {
                var result:String = null;
                for(var hash:String in this) 
                {
                        if(this[hash] == aValue)
                        {
                                result = hash;
                                break;
                        }
                }
                return result;
        }
        
        public function getValue (aKey) : Object
        {
                var hash : String = HashUtil.hash(aKey);
                return this[hash];
        }
        
        public function get IsEmpty():Boolean
        {
                for(var key:String in this) 
                {
                        return false;
                }
                return true;
        }
        
        public function get count():Number
        {
                var itemsCount:Number = 0;
                for(var key:String in this)
                {
                        itemsCount++;
                }
                return itemsCount;
        }
        
        public function clone() : IHashTable
        {
                var result : ObjectHashTable = new ObjectHashTable();
                for (var key : String in this)
                {
                        result.addWithStringKey(key, this[key]);
                }
                
                return result;
        }
        
        private function addWithStringKey (aKey : String, aObject : Object) : Void
        {
                this[aKey] = aObject;
        }
        
        private function getAllElements() : Array
        {
                var result:Array = new Array();
                for (var i : String in this) 
                {
                        result.push(this[i]);
                }
                
                return result;
        }
        
        public function getIterator () : IIterator
        {
                var list : ArrayList = new ArrayList();
                list.addAll(this.getAllElements());
                return new ArrayListIterator(list);     
        }
}

---